File size: 3,137 Bytes
f61bac1 | 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 | # SPDX-License-Identifier: BSD-3-Clause
# Copyright (c) 2024-2025, The OpenROAD Authors
function(or_integration_test_single tool_name test_name test_type check_log check_passfail)
unset(TEST_FOUND PARENT_SCOPE)
if (${test_type} STREQUAL "tcl")
set(TEST_EXT tcl)
elseif (${test_type} STREQUAL "python")
set(TEST_EXT py)
else()
message(FATAL_ERROR "${test_type} is not supported by testing")
endif()
set(TEST_FILE "${CMAKE_CURRENT_LIST_DIR}/${test_name}.${TEST_EXT}")
set(TEST_NAME "${tool_name}.${test_name}.${TEST_EXT}")
if(EXISTS "${TEST_FILE}")
add_test(
NAME ${TEST_NAME}
COMMAND ${BASH_PROGRAM} ${OpenROAD_SOURCE_DIR}/test/regression_test.sh
WORKING_DIRECTORY ${CMAKE_CURRENT_LIST_DIR}
)
string(
CONCAT ENV
"OPENROAD_EXE=$<TARGET_FILE:openroad>;"
"TEST_NAME=${test_name};"
"TEST_EXT=${TEST_EXT};"
"TEST_TYPE=${test_type};"
"TEST_CHECK_LOG=${check_log};"
"TEST_CHECK_PASSFAIL=${check_passfail};"
)
set_property(
TEST ${TEST_NAME}
PROPERTY ENVIRONMENT ${ENV}
)
set(LABELS "IntegrationTest ${test_type} ${tool_name}")
if(check_log STREQUAL "True")
set(LABELS "${LABELS} log_compare")
endif()
if(check_passfail STREQUAL "True")
set(LABELS "${LABELS} passfail")
endif()
set_tests_properties(
${TEST_NAME}
PROPERTIES LABELS "${LABELS}"
)
set(TEST_FOUND TRUE PARENT_SCOPE)
else()
set(TEST_FOUND FALSE PARENT_SCOPE)
# message(WARNING "Test ${TEST_FILE} is missing")
endif()
endfunction()
function(or_integration_tests tool_name)
# Parse args
set(options "")
set(oneValueArgs "")
set(multiValueArgs TESTS PASSFAIL_TESTS)
cmake_parse_arguments(
ARG # prefix on the parsed args
"${options}"
"${oneValueArgs}"
"${multiValueArgs}"
${ARGN}
)
if (DEFINED ARG_UNPARSED_ARGUMENTS)
message(FATAL_ERROR "Unknown argument(s) to or_integration_tests: ${ARG_UNPARSED_ARGUMENTS}")
endif()
if (DEFINED ARG_KEYWORDS_MISSING_VALUES)
message(FATAL_ERROR "Missing value for argument(s) to or_integration_tests: ${ARG_KEYWORDS_MISSING_VALUES}")
endif()
if (DEFINED ARG_TESTS)
foreach(TEST_NAME IN LISTS ARG_TESTS)
or_integration_test_single(${tool_name} ${TEST_NAME} tcl True False)
set(tcl_found ${TEST_FOUND})
or_integration_test_single(${tool_name} ${TEST_NAME} python True False)
set(py_found ${TEST_FOUND})
if(NOT tcl_found AND NOT py_found)
message(FATAL_ERROR "Test ${TEST_NAME} is missing for ${tool_name}")
endif()
endforeach()
endif()
if (DEFINED ARG_PASSFAIL_TESTS)
foreach(TEST_NAME IN LISTS ARG_PASSFAIL_TESTS)
or_integration_test_single(${tool_name} ${TEST_NAME} tcl False True)
set(tcl_found ${TEST_FOUND})
or_integration_test_single(${tool_name} ${TEST_NAME} python False True)
set(py_found ${TEST_FOUND})
if(NOT tcl_found AND NOT py_found)
message(FATAL_ERROR "Test ${TEST_NAME} is missing for ${tool_name}")
endif()
endforeach()
endif()
endfunction()
|